把趋势线数值算法带入指标实例

原代码如下：

input: N(5,1,100);
A1:=ref(h,N)=hhv(h,2*N+1);
B1:=filter(A1,N);
C1:=backset(B1,N+1);
D1:=filter(C1,n);{高点}
A2:=ref(l,N)=llv(l,2*N+1);
B2:=filter(A2,N);
C2:=backset(B2,N+1);
D2:=filter(C2,N);{低点}
E1:=(ref(llv(l,2*N),1)+ref(hhv(h,2*N),1))/2; E2:=(h+l)/2;{高低点出现在同一K线上时可作取舍}
H1:=(D1 AND not(D2 AND E1>=E2)) OR barstatus=2 OR barscount(c)=1;
L1:=(D2 AND not(D1 AND E1<E2)); H2:=D1 AND not(D2 AND E1>=E2);
X1:=ref(barslast(H1),1)+1; F1:=backset(H1 AND count(L1,X1)>0,llvbars
(if(L1,l,10000),X1));
G1:=F1>ref(F1,1); I1:=backset(G1,2); LD:=I1>ref(I1,1);{过滤后低点}
L2:=LD OR barstatus=2 OR barscount(c)=1;
X2:=ref(barslast(L2),1)+1; F2:=backset(L2 AND count(H2,X2)>0,hhvbars
(if(H2,h,0),X2));
G2:=F2>ref(F2,1); I2:=backset(G2,2); HD:=I2>ref(I2,1);{过滤后高点}
R1:=backset(barstatus=2,barslast(HD)+1);
S1:=R1>ref(R1,1); {前一高}
T1:=backset(barstatus=2,barslast(LD)+1);
U1:=T1>ref(T1,1); {前一低}
R2:=backset(S1,ref(barslast(HD),1)+2);
S2:=R2>ref(R2,1); {前二高}
T2:=backset(U1,ref(barslast(LD),1)+2);
U2:=T2>ref(T2,1); {前二低}

短期压力:drawline(S2,h,S1,h,1),Colorred;
短期支撑:drawline(U2,l,U1,l,1),Colorgreen;

现在开始将趋势线数值算法带入到此公式：

首先作者已经给出了取4个点的条件 确认H1点的是条件s2 H2点的是条件s1 L1点的是条件u2 L2点的是条件u1
那么我们先把这4个点的数值算出来 代码如下：

HH1:=if(s2,H,ref(H,BARSLAST(s2)));
HH2:=if(s1,H,ref(H,BARSLAST(s1)));
LL1:=if(u2,l,ref(l,BARSLAST(u2)));
LL2:=if(u1,l,ref(l,BARSLAST(u1)));

于是4个点的数值和4个点的条件都有了 开始带入算法公式 代码如下：

上线:HH1+(HH2-HH1)*BARSLAST(s2)/(BARSLAST(s2)-BARSLAST(s1));
下线:LL1+(LL2-LL1)*BARSLAST(U2)/(BARSLAST(U2)-BARSLAST(u1));

实现后的效果如图1：

修改后的指标附件下载：趋势线.rar


注：由于趋势线的画法是很难做到完美的 单一算法或者是单一参数都会有画错的股票 想让软件智能画出让我们满意的趋势线 还需要很复杂的智能算法 我的趋势线指标 2年里断断续续的写 到今天还未达到满意的程度 所以暂时不要希望把所有和理论上满足趋势线条件的股票都选出来 因为电脑没那么聪明 肯定有画错的股票。。。　

最后发一个实盘利用趋势线选股的案例 这是600549的月k线图 明显放量突破 如图：

，股票

标签： 趋势线 数值 算法 带入 指标 实例